vcsrepo

Table of contents

1. Overview
2. Module Description - What the module does and why it is useful
3. Setup - The basics of getting started with vcsrepo
   • Setup requirements
   • Beginning with vcsrepo
4. Usage - Configuration options and additional functionality
   • Git
   • Bazaar
   • CVS
   • Mercurial
   • Perforce
   • Subversion
5. Reference - An under-the-hood peek at what the module is doing and how
   • Type: vcsrepo
     • Providers
     • Features
6. Limitations - OS compatibility, etc.
7. Development - Guide for contributing to the module

Overview

The vcsrepo module lets you use Puppet to easily deploy content from your version control system (VCS).

Module description

The vcsrepo module provides a single type with providers to support the following version control systems:

• Git
• Bazaar
• CVS
• Mercurial
• Perforce
• Subversion

Note: This module does not have the functionality to purge or delete local changes on agent run. Note: git is the only vcs provider officially supported by Puppet Inc. Note: Release v4.0.1 has been removed from the Puppet Forge and was officially re-released as version v5.0.0 as it contained a breaking change. Details available here

Setup

Setup requirements

The vcsrepo module does not install any VCS software for you. You must install a VCS before you can use this module.

Like Puppet in general, the vcsrepo module does not automatically create parent directories for the files it manages. Set up any needed directory structures before you start.

Beginning with vcsrepo

To create and manage a blank repository, define the type vcsrepo with a path to your repository and supply the provider parameter based on the VCS you're using.

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => git,
}

Usage

Note: git is the only vcsrepo provider officially supported by Puppet Inc.

Git

Create a blank repository

To create a blank repository suitable for use as a central repository, define vcsrepo without source or revision:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => git,
}

If you're managing a central or official repository, you might want to make it a bare repository. To do this, set ensure to 'bare':

vcsrepo { '/path/to/repo':
  ensure   => bare,
  provider => git,
}

Clone/pull a repository

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => git,
  source   => 'git://example.com/repo.git',
}

To clone your repository as bare or mirror, you can set ensure to 'bare' or 'mirror':

vcsrepo { '/path/to/repo':
  ensure   => mirror,
  provider => git,
  source   => 'git://example.com/repo.git',
}

By default, vcsrepo will use the HEAD of the source repository's main branch. To use another branch or a specific commit, set revision to either a branch name or a commit SHA or tag.

Branch name:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => git,
  source   => 'git://example.com/repo.git',
  revision => 'development',
}

SHA:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => git,
  source   => 'git://example.com/repo.git',
  revision => '0c466b8a5a45f6cd7de82c08df2fb4ce1e920a31',
}

Tag:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => git,
  source   => 'git://example.com/repo.git',
  revision => '1.1.2rc1',
}

To check out a branch as a specific user, supply the user parameter:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => git,
  source   => 'git://example.com/repo.git',
  revision => '0c466b8a5a45f6cd7de82c08df2fb4ce1e920a31',
  user     => 'someUser',
}

To keep local changes while changing revision, use the keep_local_changes:

vcsrepo { '/path/to/repo':
  ensure             => present,
  provider           => git,
  source             => 'git://example.com/repo.git',
  revision           => '0c466b8a5a45f6cd7de82c08df2fb4ce1e920a31',
  keep_local_changes => true,
  user               => 'someUser',
}

To keep the repository at the latest revision, set ensure to 'latest'. Note: keep_local_changes works by stashing local changes, switching the repo to the assigned revision and, finally, unstashing the local changes. It only comes into effect if the revision parameter is different from the local repo. This parameter DOES NOT delete/purge local changes by default on every run.

WARNING: This overwrites any local changes to the repository.

vcsrepo { '/path/to/repo':
  ensure   => latest,
  provider => git,
  source   => 'git://example.com/repo.git',
  revision => 'main',
}

To clone the repository but skip initializing submodules, set submodules to 'false':

vcsrepo { '/path/to/repo':
  ensure     => latest,
  provider   => git,
  source     => 'git://example.com/repo.git',
  submodules => false,
}

To clone the repository and trust the server certificate (sslVerify=false), set trust_server_cert to 'true':

vcsrepo { '/path/to/repo':
  ensure            => present,
  provider          => git,
  source            => 'git://example.com/repo.git',
  trust_server_cert => true,
}

To use a specific umask, set umask to the desired value (expressed as a string of octal numbers); note that changes to umask do not retroactively affect repo files created earlier under a different umask. This is currently only implemented for the git provider. If unspecified, this will use the umask of the puppet process itself.

Example to set shared group access:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => git,
  source   => 'git://example.com/repo.git',
  revision => '0c466b8a5a45f6cd7de82c08df2fb4ce1e920a31',
  umask    => '0002'
}

Use HTTP or HTTPS proxies

To use an HTTP or HTTPS proxy, set http_proxy to the proxy URL. This is currently only implemented for the git provider.

git uses libcurl, so proxying of HTTPS repo URLs uses the CONNECT method, which works with either an HTTP or HTTPS proxy (since libcurl 7.52.0).

Example to use an HTTPS proxy:

vcsrepo { '/path/to/repo':
  ensure     => present,
  provider   => git,
  source     => 'https://example.com/repo.git',
  http_proxy => 'https://proxy.example.com',
  revision   => '0c466b8a5a45f6cd7de82c08df2fb4ce1e920a31',
}

Proxies can also be specified as a hash, keyed by remote, in which case vcsrepo will use the specified proxy for each remote that is used as a source (see the source parameter). For any source that does not have an http_proxy defined, no proxy will be used.

Example to use per-remote HTTPS proxies use a proxy for github but not for other remotes:

vcsrepo { '/path/to/repo':
  ensure     => present,
  provider   => git,
  source     => {
    origin => 'https://example.com/repo.git',
    github => 'https://github.com/example/repo.git',
  },
  http_proxy => {
    github => 'https://proxy2.example.com',
  },
  revision   => '0c466b8a5a45f6cd7de82c08df2fb4ce1e920a31',
}

Specification of proxies this way affects remote operations performed by vcsrepo, but does not persist the proxy settings within either the per-user git configuration or the per-repo git configuration. This means that manual operations like git fetch and git pull within vcsrepo-managed working copies will not use proxies. If you need such operations to use proxies, then you can instead configure git on a per-user or per-repository basis. Example instructions for configuring git for a user are here: https://gist.github.com/evantoli/f8c23a37eb3558ab8765

For per-repository configuration, use --local instead of --global for git config commands (or edit the .git/config file within each repo working copy).

Use multiple remotes with a repository

In place of a single string, you can set source to a hash of one or more name => URL pairs:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => git,
  remote   => 'origin'
  source   => {
    'origin'       => 'https://github.com/puppetlabs/puppetlabs-vcsrepo.git',
    'other_remote' => 'https://github.com/other_user/puppetlabs-vcsrepo.git'
  },
}

Note: If you set source to a hash, one of the names you specify must match the value of the remote parameter. That remote serves as the upstream of your managed repository.

Connect via SSH

To connect to your source repository via SSH (such as 'username@server:…'), we recommend managing your SSH keys with Puppet and using the require metaparameter to make sure they are present before the vcsrepo resource is applied.

To use SSH keys associated with a user, specify the username in the user parameter:

vcsrepo { '/path/to/repo':
  ensure   => latest,
  provider => git,
  source   => 'ssh://username@example.com/repo.git',
  user     => 'toto', #uses toto's $HOME/.ssh setup
  require  => File['/home/toto/.ssh/id_rsa'],
}

To use SSH over a nonstandard port, use the full SSH scheme and include the port number:

vcsrepo { '/path/to/repo':
  ensure   => latest,
  provider => git,
  source   => 'ssh://username@example.com:7999/repo.git',
}

Important changes in version 5

Prior to version 5.0.0 StrictHostKeyChecking was implicitly disabled when using the identity parameter. This meant that ssh would automatically add new hosts to ~/.ssh/known_hosts, letting most connections succeed.

StrictHostKeyChecking has now been removed from the options passed to ssh which will result in ssh falling back to it's default, ask. This could cause puppet runs to fail.

To ensure a run completes successfully, you should add the hosts public key to the known_hosts before the vcsrepo resource is applied.

You can usually get the public key of an ssh host by running ssh-keyscan. Adding the result to your known_hosts file may look similar to this:

ssh-keyscan -t rsa github.com >> /home/me/.ssh/known_hosts

Once everything is configured, you can continue to manage your repositories with ssh.

vcsrepo { '/path/to/repo':
  ensure   => latest,
  provider => git,
  source   => 'git@github.com:user/repo.git',
  identity => '/home/me/.ssh/id_rsa',
}

Bazaar

Create a blank repository

To create a blank repository, suitable for use as a central repository, define vcsrepo without source or revision:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => bzr,
}

Branch from an existing repository

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => bzr,
  source   => '/some/path',
}

To branch from a specific revision, set revision to a valid Bazaar revision spec:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => bzr,
  source   => '/some/path',
  revision => 'menesis@pov.lt-20100309191856-4wmfqzc803fj300x',
}

Connect via SSH

To connect to your source repository via SSH (such as 'bzr+ssh://...' or 'sftp://...,'), we recommend using the require metaparameter to make sure your SSH keys are present before the vcsrepo resource is applied:

vcsrepo { '/path/to/repo':
  ensure   => latest,
  provider => bzr,
  source   => 'bzr+ssh://bzr.example.com/some/path',
  user     => 'toto', #uses toto's $HOME/.ssh setup
  require  => File['/home/toto/.ssh/id_rsa'],
}

CVS

Create a blank repository

To create a blank repository suitable for use as a central repository, define vcsrepo without source or revision:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => cvs,
}

Checkout/update from a repository

vcsrepo { '/path/to/workspace':
  ensure   => present,
  provider => cvs,
  source   => ':pserver:anonymous@example.com:/sources/myproj',
}

To get a specific module on the current mainline, supply the module parameter:

vcsrepo { '/vagrant/lockss-daemon-source':
  ensure   => present,
  provider => cvs,
  source   => ':pserver:anonymous@lockss.cvs.sourceforge.net:/cvsroot/lockss',
  module   => 'lockss-daemon',
}

To set the GZIP compression levels for your repository history, use the compression parameter:

vcsrepo { '/path/to/workspace':
  ensure      => present,
  provider    => cvs,
  compression => 3,
  source      => ':pserver:anonymous@example.com:/sources/myproj',
}

To get a specific revision, set revision to the revision number.

vcsrepo { '/path/to/workspace':
  ensure      => present,
  provider    => cvs,
  compression => 3,
  source      => ':pserver:anonymous@example.com:/sources/myproj',
  revision    => '1.2',
}

You can also set revision to a tag:

vcsrepo { '/path/to/workspace':
  ensure      => present,
  provider    => cvs,
  compression => 3,
  source      => ':pserver:anonymous@example.com:/sources/myproj',
  revision    => 'SOMETAG',
}

Connect via SSH

To connect to your source repository via SSH, we recommend using the require metaparameter to make sure your SSH keys are present before the vcsrepo resource is applied:

vcsrepo { '/path/to/repo':
  ensure   => latest,
  provider => cvs,
  source   => ':pserver:anonymous@example.com:/sources/myproj',
  user     => 'toto', #uses toto's $HOME/.ssh setup
  require  => File['/home/toto/.ssh/id_rsa'],
}

Mercurial

Create a blank repository

To create a blank repository suitable for use as a central repository, define vcsrepo without source or revision:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => hg,
}

Clone/pull and update a repository

To get the default branch tip:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => hg,
  source   => 'http://hg.example.com/myrepo',
}

For a specific changeset, use revision:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => hg,
  source   => 'http://hg.example.com/myrepo',
  revision => '21ea4598c962',
}

You can also set revision to a tag:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => hg,
  source   => 'http://hg.example.com/myrepo',
  revision => '1.1.2',
}

To check out as a specific user:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => hg,
  source   => 'http://hg.example.com/myrepo',
  user     => 'user',
}

To specify an SSH identity key:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => hg,
  source   => 'ssh://hg@hg.example.com/myrepo',
  identity => '/home/user/.ssh/id_dsa1',
}

To specify a username and password for HTTP Basic authentication:

vcsrepo { '/path/to/repo':
  ensure              => latest,
  provider            => hg,
  source              => 'http://hg.example.com/myrepo',
  basic_auth_username => 'hgusername',
  basic_auth_password => 'hgpassword',
}

NOTE: The sensitive basic_auth_password can be deferred using the Deferred function on Puppet Master and enable to execute on agent.

vcsrepo { '/path/to/repo':
  ensure              => latest,
  provider            => hg,
  source              => 'http://hg.example.com/myrepo',
  basic_auth_username => 'hgusername',
  basic_auth_password => Deferred('sprintf', ['hgpassword']),
}

Connect via SSH

To connect to your source repository via SSH (such as 'ssh://...'), we recommend using the require metaparameter to make sure your SSH keys are present before the vcsrepo resource is applied:

vcsrepo { '/path/to/repo':
  ensure   => latest,
  provider => hg,
  source   => 'ssh://hg.example.com//path/to/myrepo',
  user     => 'toto', #uses toto's $HOME/.ssh setup
  require  => File['/home/toto/.ssh/id_rsa'],
}

Perforce

Create an empty workspace

To set up the connection to your Perforce service, set p4config to the location of a valid Perforce config file stored on the node:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => p4,
  p4config => '/root/.p4config'
}

Note: If you don't include the P4CLIENT setting in your config file, the provider generates a workspace name based on the digest of path and the node's hostname (such as puppet-91bc00640c4e5a17787286acbe2c021c).

Create/update and sync a Perforce workspace

To sync a depot path to head, set ensure to 'latest':

vcsrepo { '/path/to/repo':
  ensure   => latest,
  provider => p4,
  source   => '//depot/branch/...'
}

To sync to a specific changelist, specify its revision number with the revision parameter:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => p4,
  source   => '//depot/branch/...',
  revision => '2341'
}

You can also set revision to a label:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => p4,
  source   => '//depot/branch/...',
  revision => 'my_label'
}

Subversion

Create a blank repository

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => svn,
}

Check out from an existing repository

Provide a source pointing to the branch or tag you want to check out:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => svn,
  source   => 'svn://svnrepo/hello/branches/foo',
}

You can also designate a specific revision:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => svn,
  source   => 'svn://svnrepo/hello/branches/foo',
  revision => '1234',
}

####Checking out only specific paths

Note: The includes param is only supported when subversion client version is >= 1.6.

You can check out only specific paths in a particular repository by providing their relative paths to the includes parameter, like so:

vcsrepo { '/path/to/repo':
  ensure   => present,
  provider => svn,
  source   => 'http://svnrepo/hello/trunk',
  includes => [
    'root-file.txt',
    'checkout-folder',
    'file/this-file.txt',
    'folder/this-folder/',
  ]
}

This will create files /path/to/repo/file-at-root-path.txt and /path/to/repo/file/nested/within/repo.jmx, with folders /path/to/repo/some-folder and /path/to/repo/nested/folder/to/checkout completely recreating their corresponding working tree path.

When specified, the depth parameter will also be applied to the includes -- the root directory will be checked out using an empty depth, and the includes you specify will be checked out using the depth you provide.

To illustrate this point, using the above snippet (with the specified includes) and a remote repository layout like this:

.
├── checkout-folder
│   ├── file1
│   └── nested-1
│       ├── nested-2
│       │   └── nested-file-2
│       └── nested-file-1
├── file
│   ├── NOT-this-file.txt
│   └── this-file.txt
├── folder
│   ├── never-checked-out
│   └── this-folder
│       ├── deep-nested-1
│       │   ├── deep-nested-2
│       │   │   └── deep-nested-file-2
│       │   └── deep-nested-file-1
│       └── this-file.txt
├── NOT-this-file.txt
├── NOT-this-folder
│   ├── NOT-this-file.txt
│   └── NOT-this-one-either.txt
└── root-file.txt

With no depth given, your local folder /path/to/repo will look like this:

.
├── checkout-folder
│   ├── file1
│   └── nested-1
│       ├── nested-2
│       │   └── nested-file-2
│       └── nested-file-1
├── file
│   └── this-file.txt
├── folder
│   └── this-folder
│       ├── deep-nested-1
│       │   ├── deep-nested-2
│       │   │   └── deep-nested-file-2
│       │   └── deep-nested-file-1
│       └── this-file.txt
└── root-file.txt

And with a depth of files will look like this:

.
├── checkout-folder
│   └── file1
├── file
│   └── this-file.txt
├── folder
│   └── this-folder
│       └── this-file.txt
└── root-file.txt

####Use a specific Subversion configuration directory

Use the configuration parameter to designate the directory that contains your Subversion configuration files (typically, '/path/to/.subversion'):

vcsrepo { '/path/to/repo':
  ensure        => present,
  provider      => svn,
  source        => 'svn://svnrepo/hello/branches/foo',
  configuration => '/path/to/.subversion',
}

Connect via SSH

To connect to your source repository via SSH (such as 'svn+ssh://...'), we recommend using the require metaparameter to make sure your SSH keys are present before the vcsrepo resource is applied:

vcsrepo { '/path/to/repo':
  ensure   => latest,
  provider => svn,
  source   => 'svn+ssh://svnrepo/hello/branches/foo',
  user     => 'toto', #uses toto's $HOME/.ssh setup
  require  => File['/home/toto/.ssh/id_rsa'],
}

Reference

Type: vcsrepo

The vcsrepo module adds only one type with several providers.

For information on the classes and types, see the REFERENCE.md

Providers

Note: Not all features are available with all providers.

git - Supports the Git VCS.

Features: bare_repositories, depth, multiple_remotes, reference_tracking, ssh_identity, submodules, user

Parameters: depth, ensure, excludes, force, group, identity, owner, path, provider, remote, revision, source, user

bzr - Supports the Bazaar VCS.

Features: reference_tracking

Parameters: ensure, excludes, force, group, owner, path, provider, revision, source

cvs - Supports the CVS VCS.

Features: cvs_rsh, gzip_compression, modules, reference_tracking, user

Parameters: compression, cvs_rsh, ensure, excludes, force, group, module, owner, path, provider

hg - Supports the Mercurial VCS.

Features: reference_tracking, ssh_identity, user

Parameters: ensure, excludes, force, group, identity, owner, path, provider, revision, source, user

p4 - Supports the Perforce VCS.

Features: p4config, reference_tracking

Parameters: ensure, excludes, force, group, owner, p4config, path, provider, revision, source

svn - Supports the Subversion VCS.

Features: basic_auth, configuration, conflict, depth, filesystem_types, reference_tracking

Parameters: basic_auth_password, basic_auth_username, configuration, conflict, ensure, excludes, force, fstype, group, includes, owner, path, provider, revision, source, trust_server_cert

Features

Note: Not all features are available with all providers.

• bare_repositories - Differentiates between bare repositories and those with working copies. (Available with git.)
• basic_auth - Supports HTTP Basic authentication. (Available with hg and svn.)
• conflict - Lets you decide how to resolve any conflicts between the source repository and your working copy. (Available with svn.)
• configuration - Lets you specify the location of your configuration files. (Available with svn.)
• cvs_rsh - Understands the CVS_RSH environment variable. (Available with cvs.)
• depth - Supports shallow clones in git or sets the scope limit in svn. (Available with git and svn.)
• filesystem_types - Supports multiple types of filesystem. (Available with svn.)
• gzip_compression - Supports explicit GZip compression levels. (Available with cvs.)
• include_paths - Lets you checkout only certain paths. (Available with svn.)
• modules - Lets you choose a specific repository module. (Available with cvs.)
• multiple_remotes - Tracks multiple remote repositories. (Available with git.)
• reference_tracking - Lets you track revision references that can change over time (e.g., some VCS tags and branch names). (Available with all providers)
• ssh_identity - Lets you specify an SSH identity file. (Available with git and hg.)
• user - Can run as a different user. (Available with git, hg and cvs.)
• p4config - Supports setting the P4CONFIG environment. (Available with p4.)
• submodules - Supports repository submodules which can be optionally initialized. (Available with git.)

Limitations

Git is the only VCS provider officially supported by Puppet Inc. Git with 3.18 changes the maximum enabled TLS protocol version, this breaks some HTTPS functionality on older operating systems. They are Enterprise Linux 5 and OracleLinux 6.

The includes parameter is only supported when SVN client version is >= 1.6.

For an extensive list of supported operating systems, see metadata.json

Response to CVE-2022-24765

The vulnerability described in this CVE could impact users working on multi-user machines. A malicious actor could create a .git directory above the current working directory causing all git invocations to occur outside of a repository to read its configuration.

For a more in-depth description of this vulnerability, check out this blog post.

Fixes were released in Git versions 2.35.2 and 1:2.25.1-1ubuntu3.4 respectively.

VCSRepo users were impacted when running newer versions of Git and managing repositories that were owned by a user or group that differed from the user executing Git.

For example, setting the owner parameter on a resource would cause Puppet runs to fail with a Path /destination/path exists and is not the desired repository. error.

Impacted users are now advised to use the new safe_directory parameter on Git resources. Explicitily setting the value to true will add the current path specified on the resource to the safe.directory git configuration for the current user (global scope) allowing the Puppet run to continue without error.

Safe directory configuration will be stored within the system wide configuration file /etc/gitconfig.

Development

Puppet Inc. modules on the Puppet Forge are open projects, and community contributions are essential for keeping them great. We can't access the huge number of platforms and myriad of hardware, software, and deployment configurations that Puppet is intended to serve.

We want to keep it as easy as possible to contribute changes so that our modules work in your environment. There are a few guidelines that we need contributors to follow so that we can have a chance of keeping on top of things.

You can read the complete module contribution guide on the Puppet documentation site.

Reference

Table of Contents

Classes

• vcsrepo::manage::git: Manage the Git source code manager package
• vcsrepo::manage::svn: Manage the Subversion source code manager package

Resource types

• vcsrepo: A local version control repository

Classes

vcsrepo::manage::git

Manage the Git source code manager package

Examples

simple include

include vcsrepo::manage::git

Parameters

The following parameters are available in the vcsrepo::manage::git class:

• package_name
• package_ensure

package_name

Data type: Variant[String[1], Array[String[1]]]

name of package to manage

Default value: 'git'

package_ensure

Data type: String[1]

ensure state of the package resource

Default value: 'installed'

vcsrepo::manage::svn

Manage the Subversion source code manager package

Examples

simple include

include vcsrepo::manage::svn

Parameters

The following parameters are available in the vcsrepo::manage::svn class:

• package_name
• package_ensure

package_name

Data type: Variant[String[1], Array[String[1]]]

name of package to manage

Default value: 'subversion'

package_ensure

Data type: String[1]

ensure state of the package resource

Default value: 'installed'

Resource types

vcsrepo

A local version control repository

Properties

The following properties are available in the vcsrepo type.

ensure

Valid values: present, bare, mirror, absent, latest

Ensure the version control repository.

includes

Paths to be included from the repository

module

The repository module to manage

revision

Valid values: %r{^\S+$}

The revision of the repository

skip_hooks

Valid values: true, false

Explicitly skip any global hooks for this repository.

source

The source URI for the repository

Parameters

The following parameters are available in the vcsrepo type.

• basic_auth_password
• basic_auth_username
• branch
• compression
• configuration
• conflict
• cvs_rsh
• depth
• excludes
• force
• fstype
• group
• http_proxy
• identity
• keep_local_changes
• owner
• p4config
• path
• provider
• remote
• safe_directory
• submodules
• trust_server_cert
• umask
• user

basic_auth_password

HTTP Basic Auth password

basic_auth_username

HTTP Basic Auth username

branch

The name of the branch to clone.

compression

Compression level

configuration

The configuration directory to use

conflict

The action to take if conflicts exist between repository and working copy

cvs_rsh

The value to be used for the CVS_RSH environment variable.

depth

The value to be used to do a shallow clone.

excludes

Local paths which shouldn't be tracked by the repository

force

Valid values: true, false, yes, no

Force repository creation, destroying any files on the path in the process.

Default value: false

fstype

Filesystem type

group

The group/gid that owns the repository files

http_proxy

Sets the HTTP/HTTPS proxy for remote repo access

identity

SSH identity file

keep_local_changes

Valid values: true, false

Keep local changes on files tracked by the repository when changing revision

Default value: false

owner

The user/uid that owns the repository files

p4config

The Perforce P4CONFIG environment.

path

namevar

Absolute path to repository

provider

The specific backend to use for this vcsrepo resource. You will seldom need to specify this --- Puppet will usually discover the appropriate provider for your platform.

remote

The remote repository to track

Default value: origin

safe_directory

Valid values: true, false

Marks the current directory specified by the path parameter as a safe directory.

Default value: false

submodules

Valid values: true, false

Initialize and update each submodule in the repository.

Default value: true

trust_server_cert

Valid values: true, false

Trust server certificate

Default value: false

umask

Sets the umask to be used for all repo operations

user

The user to run for repository operations

Changelog

All notable changes to this project will be documented in this file.

The format is based on Keep a Changelog and this project adheres to Semantic Versioning.

v6.1.0 - 2023-06-13

Full Changelog

Added

• (CONT-580) - Updating readme with Deferred function for sensitive fields #610 (Ramesh7)
• Add classes to manage supported SCM packages #586 (jcpunk)

v6.0.1 - 2023-05-19

Full Changelog

Fixed

• (GH-585/CONT-998) Fix for safe_directory logic #605 (david22swan)

v6.0.0 - 2023-04-19

Full Changelog

Changed

• (CONT-803) Add Support for Puppet 8 / Drop Support for Puppet 6 #601 (david22swan)

v5.5.0 - 2023-04-19

Full Changelog

v5.4.0 - 2023-01-31

Full Changelog

Added

• support per-repo HTTP proxy for the git provider #576 (bugfood)
• support umask for git repos (try 2) #574 (bugfood)

Fixed

• Bring back GIT_SSH support for old git versions #582 (vStone)
• fix repeated acceptance tests on the same container #575 (bugfood)
• pdksync - (CONT-189) Remove support for RedHat6 / OracleLinux6 / Scientific6 #573 (david22swan)
• pdksync - (CONT-130) - Dropping Support for Debian 9 #570 (jordanbreen28)

v5.3.0 - 2022-09-13

Full Changelog

Added

• pdksync - (GH-cat-11) Certify Support for Ubuntu 22.04 #563 (david22swan)
• Add skip_hooks property to vcsrepo #557 (sp-ricard-valverde)

Fixed

• Only remove safe_directory, if it exists #566 (KoenDierckx)

v5.2.0 - 2022-06-30

Full Changelog

Added

• pdksync - (GH-cat-12) Add Support for Redhat 9 #543 (david22swan)

Fixed

• (GH-552) Fix home directory evaluation #553 (chelnak)

v5.1.0 - 2022-06-24

Full Changelog

Added

• pdksync - (IAC-1753) - Add Support for AlmaLinux 8 #524 (david22swan)
• pdksync - (IAC-1751) - Add Support for Rocky 8 #523 (david22swan)
• pdksync - (IAC-1709) - Add Support for Debian 11 #521 (david22swan)

Fixed

• (GH-535) Fix for safe directories #549 (chelnak)
• pdksync - (GH-iac-334) Remove Support for Ubuntu 14.04/16.04 #529 (david22swan)
• MODULES-11050 - Force fetch tags #527 (sp-ricard-valverde)
• pdksync - (IAC-1787) Remove Support for CentOS 6 #525 (david22swan)
• pdksync - (IAC-1598) - Remove Support for Debian 8 #522 (david22swan)

v5.0.0 - 2021-06-02

Full Changelog

Changed

• Always run as given user, even if identity set #473 (bigpresh)

v4.0.0 - 2021-03-03

Full Changelog

Changed

• pdksync - Remove Puppet 5 from testing and bump minimal version to 6.0.0 #491 (carabasdaniel)

v3.2.1 - 2021-02-19

Full Changelog

Fixed

• (MODULES-9997) - Removing extra unwrap on Sensitive value #490 (pmcmaw)

v3.2.0 - 2021-01-20

Full Changelog

Added

• pdksync - (feat) - Add support for Puppet 7 #476 (daianamezdrea)
• pdksync - (IAC-973) - Update travis/appveyor to run on new default branch main #466 (david22swan)

Fixed

• [MODULES-10857] Rename exist function to exists in cvs.rb #484 (carabasdaniel)
• (IAC-1223) Correct clone https test #471 (pmcmaw)
• check if pass containes non-ASCII chars before provider is created #464 (adrianiurca)

v3.1.1 - 2020-06-26

Full Changelog

Fixed

• prevent ANSI color escape sequences from messing up git output #458 (kenyon)
• Unset GIT_SSH_COMMAND before exec'ing git command #435 (mzagrabe)

v3.1.0 - 2019-12-10

Full Changelog

Added

• (FM-8234) Port to Litmus #429 (sheenaajay)
• pdksync - Add support on Debian10 #428 (lionce)
• feature(git): add keep local changes option #425 (jfroche)

Fixed

• feat: do not chown excluded files #432 (jfroche)

v3.0.0 - 2019-06-14

Full Changelog

Added

• (FM-8035) Add RedHat 8 support #419 (eimlav)
• (MODULES-8738) Allow Sensitive value for basic_auth_password #416 (eimlav)
• (MODULES-8140) - Add SLES 15 support #399 (eimlav)

Changed

• pdksync - (MODULES-8444) - Raise lower Puppet bound #413 (david22swan)

Fixed

• MODULES-8910 fix for failing git install using RepoForge instead of epel #414 (Lavinia-Dan)
• (maint) Add HTML anchor tag #404 (clairecadman)
• pdksync - (FM-7655) Fix rubygems-update for ruby < 2.3 #401 (tphoney)

2.4.0 - 2018-09-28

Full Changelog

Added

• pdksync - (FM-7392) - Puppet 6 Testing Changes #394 (pmcmaw)
• pdksync - (MODULES-6805) metadata.json shows support for puppet 6 #393 (tphoney)
• pdksync - (MODULES-7658) use beaker4 in puppet-module-gems #390 (tphoney)
• (MODULES-7467) Update Vcsrepo to support Ubuntu 18.04 #382 (david22swan)

Fixed

• (MODULES-7009) Do not run HTTPS tests on old OSes #384 (tphoney)
• Improve Git performance when using SHA revisions #380 (vpierson)
• [FM-6957] Removing unsupported OS from Vcsrepo #378 (david22swan)
• Avoid popup on macOS when developer tools aren't installed #367 (girardc79)

2.3.0 - 2018-01-19

Full Changelog

Added

• (MODULES-5889) Added trust_server_cert support to Git provider #360 (eputnam)

2.2.0 - 2017-10-30

Full Changelog

2.1.0 - 2017-10-23

Full Changelog

Fixed

• (MODULES-5704) Fix cvs working copy detection #349 (vicinus)
• [MODULES-5615] Fix for working_copy_exists #345 (martinmoerch)
• Git: Do not set branch twice #335 (sathieu)

2.0.0 - 2017-06-30

Full Changelog

Fixed

• fixing force parameter to be boolean #332 (hunner)
• Fix to get svn provider working again #322 (Rocco83)
• Fix Solaris sh-ism #311 (pearcec)

1.5.0 - 2016-12-16

Full Changelog

Added

• Adding svn provider support for versioning of individual files #274 (squarebracket)

Fixed

• [MODULES-4139] Fix CI failures in CI on ubuntu 16.04 caused by regex matching on 16.04 when it is not meant to. #312 (wilson208)
• Fix muliple default provider warning on windows #310 (pearcec)
• [MODULES-3998] Fix to GIT and SVN providers to support older versions of git and svn #306 (wilson208)

1.4.0 - 2016-09-06

Full Changelog

Added

• Update metadata to note Debian 8 support #286 (DavidS)
• Add mirror option for git cloning #282 (Strech)

Fixed

• Fix bug in ensure => absent #293 (butlern)
• fix branch existence determintaion functionality #277 (godlikeachilles)

1.3.2 - 2015-12-04

Full Changelog

Added

• Add feature 'depth' and parameter 'trust_server_cert' to svn #269 (monai)
• Autorequire Package['mercurial'][#262](https://github.com/puppetlabs/puppetlabs-vcsrepo/pull/262) (mpdude)

Fixed

• Fix :false to be default value #273 (hunner)
• MODULES-1232 Make sure HOME is set correctly #265 (underscorgan)
• Fix acceptance hang #264 (hunner)
• MODULES-1800 - fix case where ensure => latest and no revision specified #260 (underscorgan)

1.3.1 - 2015-07-27

Full Changelog

Added

• Add helper to install puppet/pe/puppet-agent #254 (hunner)
• acceptance: Add a test verifying anonymous https cloning #252 (DavidS)

Fixed

• fix for detached HEAD on git 2.4+ #256 (keeleysam)
• Make sure the embedded SSL cert doesn't expire #242 (BillWeiss)

1.3.0 - 2015-05-19

Full Changelog

Added

• (BKR-147) add Gemfile setting for BEAKER_VERSION for puppet... #238 (anodelman)
• Add IntelliJ files to the ignore list #226 (cmurphy)
• Add support for 'conflict' parameter to populate svn --accept arg #220 (ddisisto)
• Add submodules feature to git provider #218 (dduvnjak)

Fixed

• Fix remote hash ordering for unit tests #240 (cmurphy)
• MODULES-1596 - Repository repeatedly destroyed/created with force #225 (underscorgan)
• Fix for MODULES-1597: "format" is a file not a directory #223 (Farzy)

1.2.0 - 2014-11-04

Full Changelog

Added

• Add user feature support to CVS provider #213 (jfautley)
• Handle both Array/Enumerable and String values for excludes parameter #207 (sodabrew)
• Change uid by Puppet execution API #200 (pbrit)

Fixed

• Fix issue with puppet_module_install, removed and using updated method f... #204 (cyberious)

1.1.0 - 2014-07-15

Full Changelog

Added

• (MODULES-1014) Add rspec for noop mode #189 (petems)

Fixed

• Fix metadata.json to match checksum #195 (hunner)
• Fix lint errors #192 (hunner)
• Update README.markdown to fix the formatting around the officially supported note. #191 (klynton)
• (MODULES-660) Correct detached HEAD on latest #173 (hunner)

1.0.2 - 2014-07-01

Full Changelog

Added

• Add supported information and reorder to highlight support #180 (lrnrthr)
• Rebase of PR #177 - Add HG Basic Auth #178 (sodabrew)

Fixed

• Fix issue with node changing every checkin #181 (jbussdieker)

1.0.1 - 2014-06-19

Full Changelog

Added

• Pin versions in the supported branch. #158 (underscorgan)
• (MODULES-1014) Adding noop mode option #153 (petems)

Fixed

• Correct shallow clone count #166 (hunner)
• Fix typo in mkdir #164 (hunner)

1.0.0 - 2014-06-04

Full Changelog

Added

• Add optional keyfile argument to rake tasks #150 (johnduarte)
• Add beaker tests to complete test plan #141 (johnduarte)
• Add rake tasks to test both beaker and beaker-rspec in one go #140 (cyberious)
• Add test for ensure latest with branch specified #137 (johnduarte)
• Add acceptance tests for git protocols using clone #135 (johnduarte)
• add beaker-rspec support #130 (Phil0xF7)
• Only add ssh options to commands that actually talk to the network. #121 (fkrull)
• Add the option to shallow clones with git #114 (freyes)

Fixed

• Update specs and fix FM-1361 #145 (hunner)
• Fix detached head state #139 (cyberious)
• Fix issue where force=>true was not destroying repository then recreatin... #138 (cyberious)
• git: actually use the remote parameter #115 (mciurcio)
• Bug fix: Git provider on_branch? retains trailing newline #109 (mikegerwitz)
• Correctly handle detached head for 'latest' on latest Git versions #106 (mikegerwitz)
• Don't 'su' if passed user is current user #105 (mcanevet)

0.2.0 - 2013-11-13

Full Changelog

Added

• Add autorequire for Package['git'][#98](https://github.com/puppetlabs/puppetlabs-vcsrepo/pull/98) (reidmv)
• Add a blank dependencies section and stringify versions. #96 (apenney)
• FM-103: Add metadata.json to all modules. #95 (apenney)
• added support for changing upstream repo url - rebase of #74 #84 (sodabrew)
• Add support for master svn repositories #83 (sodabrew)
• Allow for setting the CVS_RSH environment variable #82 (mpdude)
• Add user and ssh identity to the Mercurial provider. #77 (arnoudj)
• Add travis build-status image #76 (pbrit)
• Add timeout to ssh connections #65 (rkhatibi)
• "ensure => latest" support for bzr #61 (hholzgra)

Fixed

• Correct use of withenv #86 (sodabrew)

0.1.2 - 2013-03-25

Full Changelog

Added

• Allows the creation of non-root repositories #57 (binford2k)

0.1.1 - 2012-10-30

Full Changelog

Added

• Add a dummy provider, remove 'defaultfor' from all other providers. #35 (sodabrew)
• Adds comma to last attribute to comply with style #31 (ghoneycutt)
• Add default user to run git as. #27 (ody)

0.1.0 - 2012-10-12

Full Changelog

Added

• Add the ability to specify a git remote #24 (jesusaurus)
• Improved Puppet DSL style as per the guidelines. #19 (adamgibbins)

Fixed

• (#16495, #15660) Fix regression for notifications and pulls on git provider #33 (kbarber)
• Checkout git repository as user, fixed ensure latest, ssh options #25 (ejhayes)
• Fix failing hg provider spec #23 (jmchilton)
• don't recreate bare repo if it exists already - fixes http://projects.puppetlabs.com/issues/12303 #18 (andreasgerstmayr)
• (#11798) Fix git checkout of revisions #17 (mmrobins)

0.0.5 - 2011-12-26

Full Changelog

Added

• Added missing 'working_copy_exists?' method. #16 (mfournier)
• Fix (#10788) - Avoid unnecessary remote operations in the vcsrepo type #14 ()
• Suggested fix for (#10751) by adding a "module" parameter #13 ()

Fixed

• Fix (#10787) - Various fixes/tweaks for the CVS provider #15 ()
• Fix (#9083) as suggested by the original bug reporter. #12 ()
• Bug Fix: Some ownerships in .git directory are 'root' after vcsrepo's retrieve is called #11 (cPanelScott)
• Fix (#10440) by making all commands optional #9 ()

0.0.4 - 2011-09-21

Full Changelog