Defined Type: oradb::goldengate

Defined in:
manifests/goldengate.pp

Overview

goldengate

install goldengate version 12.1.2 or 11.2

Examples:

goldengate install


oradb::goldengate{ 'ggate12.1.2':
  version                    => '12.1.2',
  file                       => '121210_fbo_ggs_Linux_x64_shiphome.zip',
  database_type              => 'Oracle',
  database_version           => 'ORA12c',
  database_home              => '/oracle/product/12.1/db',
  oracle_base                => '/oracle',
  goldengate_home            => '/oracle/product/12.1/ggate',
  manager_port               => 16000,
  user                       => 'oracle',
  group                      => 'dba',
  group_install              => 'oinstall',
  download_dir               => '/var/tmp/install',
  puppet_download_mnt_point  => '/software',
}

oradb::goldengate{ 'ggate11.2.1':
  version                    => '11.2.1',
  file                       => 'ogg112101_fbo_ggs_Linux_x64_ora11g_64bit.zip',
  tar_file                   => 'fbo_ggs_Linux_x64_ora11g_64bit.tar',
  goldengate_home            => "/oracle/product/11.2.1/ggate",
  user                       => 'oracle',
  group                      => 'dba',
  download_dir               => '/var/tmp/install',
  puppet_download_mnt_point  => '/software',

Parameters:

  • version (String) (defaults to: '12.2.1')

    goldengate software version

  • file (String) (defaults to: undef)

    goldengate installation file

  • tar_file (Optional[String]) (defaults to: undef)

    tar file inside zip for 11g version

  • database_type (Enum['Oracle']) (defaults to: 'Oracle')

    goldengate db version only for 12c

  • database_version (Enum['ORA11g', 'ORA12c']) (defaults to: 'ORA11g')

    for oracle database 11g or 12c only for 12c

  • oracle_base (Optional[String]) (defaults to: undef)

    oracle base directory only for 12c

  • ora_inventory_dir (Optional[String]) (defaults to: undef)

    full path to the oracle inventory directory only for 12c

  • database_version (defaults to: 'ORA11g')

    for oracle database 11g or 12c only for 12c

  • oracle_base (defaults to: undef)

    oracle base directory only for 12c

  • ora_inventory_dir (defaults to: undef)

    full path to the oracle inventory directory only for 12c

  • manager_port (Optional[Integer]) (defaults to: undef)

    manager port number

  • goldengate_home (String) (defaults to: undef)

    full path to the goldengate home under oracle base

  • user (String) (defaults to: 'ggate')

    operating system username

  • group (String) (defaults to: lookup('oradb::group'))

    operating system group name

  • group_install (String) (defaults to: lookup('oradb::group_install'))

    operating system group install name

  • puppet_download_mnt_point (String) (defaults to: lookup('oradb::module_mountpoint'))

    the location where the installation software is available

  • download_dir (String) (defaults to: lookup('oradb::download_dir'))

    location for installation files used by this module

  • database_home (Optional[String]) (defaults to: undef)

    the oracle database home for connecting goldengat only for 12c



53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
# File 'manifests/goldengate.pp', line 53

define oradb::goldengate(
  String $version                            = '12.2.1',
  String $file                               = undef,
  Optional[String] $tar_file                 = undef,     # only for < 12.1.2
  Enum['Oracle'] $database_type              = 'Oracle',  # only for > 12.1.2
  Enum['ORA11g', 'ORA12c'] $database_version = 'ORA11g',  # only for > 12.1.2
  Optional[String] $database_home            = undef,     # only for > 12.1.2
  Optional[String] $oracle_base              = undef,     # only for > 12.1.2
  Optional[String] $ora_inventory_dir        = undef,     # only for > 12.1.2
  String $goldengate_home                    = undef,
  Optional[Integer] $manager_port            = undef,
  String $user                               = 'ggate',
  String $group                              = lookup('oradb::group'),
  String $group_install                      = lookup('oradb::group_install'),
  String $download_dir                       = lookup('oradb::download_dir'),
  String $puppet_download_mnt_point          = lookup('oradb::module_mountpoint'),
)
{
  $exec_path = lookup('oradb::exec_path')

  if ( $version in ['12.1.2', '12.2.1'] ) {
    # check if the oracle software already exists
    if ( $database_home == undef or is_string($database_home) == false) {fail('You must specify a database_home') }
    if ( $oracle_base == undef or is_string($oracle_base) == false) {fail('You must specify an oracle_base') }
    if ( $manager_port == undef or is_integer($manager_port) == false) {fail('You must specify a manager_port') }

    $found = oradb::oracle_exists( $goldengate_home )

    if $found == undef {
      $continue = true
    } else {
      if ( $found ) {
        $continue = false
      } else {
        notify {"oradb::goldengate ${goldengate_home} does not exists":}
        $continue = true
      }
    }
  } else {
    $continue = false
  }

  if ( $version in ['12.1.2', '12.2.1'] ) {
    if $ora_inventory_dir == undef {
      $ora_inventory = oradb::cleanpath("${oracle_base}/../oraInventory")
    } else {
      validate_absolute_path($ora_inventory_dir)
      $ora_inventory = "${ora_inventory_dir}/oraInventory"
    }

    db_directory_structure{"oracle goldengate structure ${version}":
      ensure            => present,
      oracle_base_dir   => $oracle_base,
      ora_inventory_dir => $ora_inventory,
      download_dir      => $download_dir,
      os_user           => $user,
      os_group          => $group_install,
    }
  }

  # only for 12.1.2
  if ( $continue == true ) {

    $ggate_install_dir = 'fbo_ggs_Linux_x64_shiphome'

    file { "${download_dir}/${file}":
      source  => "${puppet_download_mnt_point}/${file}",
      owner   => $user,
      group   => $group,
      require => Db_directory_structure["oracle goldengate structure ${version}"],
    }

    exec { 'extract gg':
      command   => "unzip -o ${download_dir}/${file} -d ${download_dir}",
      creates   => "${download_dir}/${ggate_install_dir}",
      timeout   => 0,
      path      => $exec_path,
      user      => $user,
      group     => $group,
      logoutput => false,
      require   => File["${download_dir}/${file}"],
    }

    file { "${download_dir}/oggcore.rsp":
      content => epp("oradb/oggcore_${version}.rsp.epp", {
                      'database_version' => $database_version,
                      'goldengate_home'  => $goldengate_home,
                      'database_home'    => $database_home,
                      'ora_inventory'    => $ora_inventory,
                      'group_install'    => $group_install,
                      'manager_port'     => $manager_port }),
      owner   => $user,
      group   => $group,
      require => Db_directory_structure["oracle goldengate structure ${version}"],
    }

    oradb::utils::dborainst{"ggate orainst ${version}":
      ora_inventory_dir => $ora_inventory,
      os_group          => $group_install,
    }

    exec { 'install oracle goldengate':
      command   => "/bin/sh -c 'unset DISPLAY;${download_dir}/${ggate_install_dir}/Disk1/runInstaller -silent -waitforcompletion -responseFile ${download_dir}/oggcore.rsp'",
      require   => [File["${download_dir}/oggcore.rsp"],
                    Oradb::Utils::Dborainst["ggate orainst ${version}"],
                    Exec['extract gg'],],
      creates   => $goldengate_home,
      timeout   => 0,
      path      => $exec_path,
      logoutput => true,
      user      => $user,
      group     => $group_install,
      returns   => [3,0],
    }

  }

  if ( $version != '12.1.2' and $version != '12.2.1'){

    if ( $tar_file == undef or is_string($tar_file) == false) {fail("${title} You must specify a tar_file") }

    # # check oracle install folder
    # if !defined(File[$download_dir]) {
    #   file { $download_dir:
    #     ensure  => directory,
    #     recurse => false,
    #     replace => false,
    #     mode    => '0777',
    #   }
    # }

    #version is different, use the old way
    file { "${download_dir}/${file}":
      source => "${puppet_download_mnt_point}/${file}",
      owner  => $user,
      group  => $group,
    }

    exec { "extract gg ${title}":
      command   => "unzip -o ${download_dir}/${file} -d ${download_dir}",
      require   => File["${download_dir}/${file}"],
      creates   => "${download_dir}/${tar_file}",
      timeout   => 0,
      path      => $exec_path,
      user      => $user,
      group     => $group,
      logoutput => true,
    }

    file { $goldengate_home :
      ensure  => directory,
      recurse => false,
      replace => false,
      mode    => '0775',
      owner   => $user,
      group   => $group,
    }

    exec { "extract tar ${title}":
      command   => "tar -xf ${download_dir}/${tar_file} -C ${goldengate_home}",
      require   => [File[$goldengate_home],
                    Exec["extract gg ${title}"]],
      creates   => "${goldengate_home}/ggsci",
      timeout   => 0,
      path      => $exec_path,
      user      => $user,
      group     => $group,
      logoutput => true,
    }
  }
}