Ensures that a given line is contained within a file. The implementation matches the full line, including whitespace at the beginning and end. If the line is not contained in the given file, Puppet will append the line to the end of the file to ensure the desired state. Multiple resources may be declared to manage multiple lines in the same file.

Example:

    file_line { 'sudo_rule':
      path => '/etc/sudoers',
      line => '%sudo ALL=(ALL) ALL',
    }

    file_line { 'sudo_rule_nopw':
      path => '/etc/sudoers',
      line => '%sudonopw ALL=(ALL) NOPASSWD: ALL',
    }

In this example, Puppet will ensure both of the specified lines are
contained in the file /etc/sudoers.

Match Example:

    file_line { 'bashrc_proxy':
      ensure => present,
      path   => '/etc/bashrc',
      line   => 'export HTTP_PROXY=http://squid.puppetlabs.vm:3128',
      match  => '^export HTTP_PROXY=',
    }

In this code example match will look for a line beginning with export
followed by HTTP_PROXY and replace it with the value in line.

Match Example With `ensure => absent`:

    file_line { 'bashrc_proxy':
      ensure            => absent,
      path              => '/etc/bashrc',
      line              => 'export HTTP_PROXY=http://squid.puppetlabs.vm:3128',
      match             => '^export HTTP_PROXY=',
      match_for_absence => true,
    }

In this code example match will look for a line beginning with export
followed by HTTP_PROXY and delete it.  If multiple lines match, an
error will be raised unless the `multiple => true` parameter is set.

**Autorequires:** If Puppet is managing the file that will contain the line
being managed, the file_line resource will autorequire that file.

A simple resource type intended to be used as an anchor in a composite class.

In Puppet 2.6, when a class declares another class, the resources in the interior class are not contained by the exterior class. This interacts badly with the pattern of composing complex modules from smaller classes, as it makes it impossible for end users to specify order relationships between the exterior class and other modules.

The anchor type lets you work around this. By sandwiching any interior classes between two no-op resources that are contained by the exterior class, you can ensure that all resources in the module are contained.

  class ntp {
    # These classes will have the correct order relationship with each
    # other. However, without anchors, they won't have any order
    # relationship to Class['ntp'].
    class { 'ntp::package': }
    -> class { 'ntp::config': }
    -> class { 'ntp::service': }

    # These two resources "anchor" the composed classes within the ntp
    # class.
    anchor { 'ntp::begin': } -> Class['ntp::package']
    Class['ntp::service']    -> anchor { 'ntp::end': }
  }

This allows the end user of the ntp module to establish require and before relationships with Class['ntp']:

  class { 'ntp': } -> class { 'mcollective': }
  class { 'mcollective': } -> class { 'ntp': }