chocolatey

Chocolatey for Business Now Available!

We're excited for you to learn more about what's available in the Business editions!

Table of Contents

1. Overview
2. Module Description - What the chocolatey module does and why it is useful
   • Why Chocolatey
3. Setup - The basics of getting started with chocolatey
   • What chocolatey affects
   • Setup requirements
   • Beginning with Chocolatey provider
4. Usage - Configuration options and additional functionality
5. Reference
   • Facts)
6. Limitations - OS compatibility, etc.
   • Known Issues
7. Development - Guide for contributing to the module
8. Attributions

Overview

This is a Puppet package provider for Chocolatey, which is like apt-get, but for Windows. Check the module's metadata.json for compatible Puppet and Puppet Enterprise versions.

Module Description

This is the official module for working with the Chocolatey package manager. There are two versions available:

• puppetlabs/chocolatey
  • This is the stable version and is commercially supported by Puppet.
  • It is slower moving, but offers greater stability and fewer changes.
• chocolatey/chocolatey
  • This is the bleeding edge version and is not commercially supported by Puppet.
  • It keeps up with all the new features, but is not as fully tested.

This module supports all editions of Chocolatey, including FOSS, Professional and Chocolatey for Business.

This module is able to:

• Install Chocolatey
• Work with custom location installations
• Configure Chocolatey
• Use Chocolatey as a package provider

Why Chocolatey

Chocolatey closely mimics how package managers on other operating systems work. If you can imagine the built-in provider for Windows versus Chocolatey, take a look at the use case of installing git:

# Using built-in provider
package { "Git version 1.8.4-preview20130916":
  ensure    => installed,
  source    => 'C:\temp\Git-1.8.4-preview20130916.exe',
  install_options => ['/VERYSILENT']
}

# Using Chocolatey (set as default for Windows)
package { 'git':
  ensure   => latest,
}

With the built-in provider:

• The package name must match exactly the name from installed programs.
• The package name has issues with unicode characters.
• The source must point to the location of the executable installer.
• It cannot ensure => latest. Read about handling versions and upgrades in the Puppet documentation.

With Chocolatey's provider:

• The package name only has to match the name of the package, which can be whatever you choose.
• The package knows how to install the software silently.
• The package knows where to get the executable installer.
• The source is able to specify different Chocolatey feeds.
• Chocolatey makes package more platform agnostic, because it looks exactly like other platforms.

For reference, read about the provider features available from the built-in provider, compared to other package managers:

Setup

What Chocolatey affects

Chocolatey affects your system and what software is installed on it, ranging from tools and portable software, to natively installed applications.

Setup Requirements

Chocolatey requires the following components:

• Powershell v2+ (Installed on most systems by default)
• .NET Framework v4+

Beginning with Chocolatey provider

Install this module via any of these approaches:

• Puppet Forge
• git-submodule (tutorial)
• librarian-puppet
• r10k

Usage

Manage Chocolatey installation

Ensure Chocolatey is installed and configured:

include chocolatey

Override default Chocolatey install location

class {'chocolatey':
  choco_install_location => 'D:\secured\choco',
}

NOTE: This will affect suitability on first install. There are also special considerations for C:\Chocolatey as an install location, see choco_install_location for details.

Use an internal chocolatey.nupkg for Chocolatey installation

class {'chocolatey':
  chocolatey_download_url         => 'https://internalurl/to/chocolatey.nupkg',
  use_7zip                        => false,
  choco_install_timeout_seconds   => 2700,
}

Use a file chocolatey.0.9.9.9.nupkg for installation

class {'chocolatey':
  chocolatey_download_url         => 'file:///c:/location/of/chocolatey.0.9.9.9.nupkg',
  use_7zip                        => false,
  choco_install_timeout_seconds   => 2700,
}

Specify the version of chocolatey by class parameters

class {'chocolatey':
  chocolatey_download_url         => 'file:///c:/location/of/chocolatey.0.9.9.9.nupkg',
  use_7zip                        => false,
  choco_install_timeout_seconds   => 2700,
  chocolatey_version              => '0.9.9.9',
}

Log chocolatey bootstrap installer script output

class {'chocolatey':
  log_output              => true,
}

Install chocolatey using a proxy server

class {'chocolatey':
  install_proxy => 'http://proxy.megacorp.com:3128',
}

Configuration

If you have Chocolatey 0.9.9.x or above, you can take advantage of configuring different aspects of Chocolatey.

Sources Configuration

You can specify sources that Chocolatey uses by default, along with priority.

Requires Chocolatey v0.9.9.0+.

Disable the default community repository source

chocolateysource {'chocolatey':
  ensure => disabled,
}

Set a priority on a source

chocolateysource {'chocolatey':
  ensure   => present,
  location => 'https://chocolatey.org/api/v2',
  priority => 1,
}

Add credentials to a source

chocolateysource {'sourcename':
  ensure   => present,
  location => 'https://internal/source',
  user     => 'username',
  password => 'password',
}

NOTE: Chocolatey encrypts the password in a way that is not verifiable. If you need to rotate passwords, you cannot use this resource to do so unless you also change the location, user, or priority (because those are ensurable properties).

NOTE: The sensitive password can be deferred using the Deferred function on Puppet Master and enable to execute on agent.

chocolateysource {'sourcename':
  ensure   => present,
  location => 'https://internal/source',
  user     => 'username',
  password => Deferred('sprintf', ['password']),
}

Features Configuration

You can configure features that Chocolatey has available. Run choco feature list to see the available configuration features.

Requires Chocolatey v0.9.9.0+.

Enable Auto Uninstaller

Uninstall from Programs and Features without requiring an explicit uninstall script.

chocolateyfeature {'autouninstaller':
  ensure => enabled,
}

Disable Use Package Exit Codes

Requires 0.9.10+ for this feature.

Use Package Exit Codes - Allows package scripts to provide exit codes. With this enabled, Chocolatey uses package exit codes for exit when non-zero (this value can come from a dependency package). Chocolatey defines valid exit codes as 0, 1605, 1614, 1641, 3010. With this feature disabled, Chocolatey exits with a 0 or a 1 (matching previous behavior).

Note that this behavior may cause Puppet to think that the run has failed. We advise that you leave this at the default setting or disable it. Do not enable it.

chocolateyfeature {'usepackageexitcodes':
  ensure => disabled,
}

Enable Virus Check

Requires 0.9.10+ and Chocolatey Pro / Business for this feature.

Virus Check - Performs virus checking on downloaded files. (Licensed versions only.)

chocolateyfeature {'viruscheck':
  ensure => enabled,
}

Enable FIPS Compliant Checksums

Requires 0.9.10+ for this feature.

Use FIPS Compliant Checksums - Ensures checksumming done by Chocolatey uses FIPS compliant algorithms. Not recommended unless required by FIPS Mode. Enabling on an existing installation could have unintended consequences related to upgrades or uninstalls.

chocolateyfeature {'usefipscompliantchecksums':
  ensure => enabled,
}

Config configuration

You can configure config values that Chocolatey has available. Run choco config list to see the config settings available (just the config settings section).

Requires Chocolatey v0.9.10.0+.

Set cache location

The cache location defaults to the TEMP directory. You can set an explicit directory to cache downloads to instead of the default.

chocolateyconfig {'cachelocation':
  value  => "c:\\downloads",
}

Unset cache location

Removes cache location setting, returning the setting to its default.

chocolateyconfig {'cachelocation':
  ensure => absent,
}

Use an explicit proxy

When using Chocolatey behind a proxy, set proxy and optionally proxyUser and proxyPassword.

NOTE: The proxyPassword value is not verifiable.

chocolateyconfig {'proxy':
  value  => 'https://someproxy.com',
}

chocolateyconfig {'proxyUser':
  value  => 'bob',
}

# not verifiable
chocolateyconfig {'proxyPassword':
  value  => 'securepassword',
}

NOTE: The sensitive value can be deferred using the Deferred function on Puppet Master and enable to execute on agent.

chocolateyconfig {'proxyPassword':
  value  => Deferred('sprintf', ['securepassword']),
}

Set Chocolatey as Default Windows Provider

If you want to set this provider as the site-wide default, add to your site.pp:

if $::kernel == 'windows' {
  Package { provider => chocolatey, }
}

# OR

case $operatingsystem {
  'windows': {
    Package { provider => chocolatey, }
  }
}

Packages

With all options

package { 'notepadplusplus':
  ensure            => installed|latest|'1.0.0'|'>=1.0 <2.0'|absent,
  provider          => 'chocolatey',
  install_options   => ['-pre','-params','"','param1','param2','"'],
  uninstall_options => ['-r'],
  source            => 'https://myfeed.example.com/api/v2',
  package_settings  => { 'verbose' => true, 'log_output' => true, },
}

• Supports installable and uninstallable.
• Supports versionable so that ensure => '1.0' works.
• Supports version_range so that ensure => '>=1.0 <2.0' works.
• Supports upgradeable.
• Supports latest (checks upstream), absent (uninstall).
• Supports install_options for pre-release, and other command-line options.
• Supports uninstall_options for pre-release, and other command-line options.
• Supports holdable, requires Chocolatey v0.9.9.0+.
• Uses package_settings to pass flags to the chocolatey provider.

Simple install

package { 'notepadplusplus':
  ensure   => installed,
  provider => 'chocolatey',
}

To always ensure using the newest version available

package { 'notepadplusplus':
  ensure   => latest,
  provider => 'chocolatey',
}

To ensure a specific version

package { 'notepadplusplus':
  ensure   => '6.7.5',
  provider => 'chocolatey',
}

To ensure a version range

package { 'notepadplusplus':
  ensure   => '>=6.7.5 <7.0',
  provider => 'chocolatey',
}

To specify custom source

package { 'notepadplusplus':
  ensure   => '6.7.5',
  provider => 'chocolatey',
  source   => 'C:\local\folder\packages',
}

package { 'notepadplusplus':
  ensure   => '6.7.5',
  provider => 'chocolatey',
  source   => '\\unc\source\packages',
}

package { 'notepadplusplus':
  ensure   => '6.7.5',
  provider => 'chocolatey',
  source   => 'https://custom.nuget.odata.feed/api/v2/',
}

package { 'notepadplusplus':
  ensure   => '6.7.5',
  provider => 'chocolatey',
  source   => 'C:\local\folder\packages;https://chocolatey.org/api/v2/',
}

Install options with spaces

Spaces in arguments must always be covered with a separation. Shown below is an example of how you configure -installArgs "/VERYSILENT /NORESTART".

package {'launchy':
  ensure          => installed,
  provider        => 'chocolatey',
  install_options => ['-override', '-installArgs', '"', '/VERYSILENT', '/NORESTART', '"'],
}

Install options with quotes or spaces

The underlying installer may need quotes passed to it. This is possible, but not as intuitive. The example below covers passing /INSTALLDIR="C:\Program Files\somewhere".

For this to be passed through with Chocolatey, you need a set of double quotes surrounding the argument and two sets of double quotes surrounding the item that must be quoted (see how to pass/options/switches). This makes the string look like -installArgs "/INSTALLDIR=""C:\Program Files\somewhere""" for proper use with Chocolatey.

Then, for Puppet to handle that appropriately, you must split on every space. Yes, on every space you must split the string or the result comes out incorrectly. This means it will look like the following:

install_options => ['-installArgs',
  '"/INSTALLDIR=""C:\Program', 'Files\somewhere"""']

Make sure you have all of the right quotes - start it off with a single double quote, then two double quotes, then close it all by closing the two double quotes and then the single double quote or a possible three double quotes at the end.

package {'mysql':
  ensure          => latest,
  provider        => 'chocolatey',
  install_options => ['-override', '-installArgs',
    '"/INSTALLDIR=""C:\Program', 'Files\somewhere"""'],
}

You can split it up a bit for readability if it suits you:

package {'mysql':
  ensure          => latest,
  provider        => 'chocolatey',
  install_options => ['-override', '-installArgs', '"'
    '/INSTALLDIR=""C:\Program', 'Files\somewhere""',
    '"'],
}

Note: The above is for Chocolatey v0.9.9+. You may need to look for an alternative method to pass args if you have 0.9.8.x and below.

A warning about secrets in install_options

There is no guarantee that secrets in install_options will not show up in debug runs of either puppet agent or puppet apply calls.

This is another reason to not set your production runs to debug mode.

However, this information is not written to puppetdb or any other Puppet logs.

It is written to the Chocolatey log on each machine unless you have C4B and use the --package-parameters-sensitive or --install-arguments-sensitive Chocolatey parameters, which will redact specified values from the Chocolatey log.

For more information on these Chocolatey parameters, see the Chocolatey reference documentation on the install command and the upgrade command.

If you need to include a secret in your install_options, do not run in debug mode in production and use C4B and the --package-parameters-sensitive or --install-arguments-sensitive Chocolatey parameter.

Passing Flags With Package Settings

You can pass flags to the chocolatey provider using package_settings. You might want to do this in a default:

    Package {
      package_settings => { 'verbose' => true, 'log_output' => true, },
    }

• "verbose" causes calls to chocolatey to output information about what they're about to do; this is because some things, in particular "ensure => latest", are pretty slow, which can lead to long periods where Puppet appears to be doing nothing.
  • When Chocolatey is version 0.10.4 or later and "Verbose" is not specified as true Chocolatey will be run with the --no-progress parameter, limiting the erroneous output of download information to the logs.
• "log_output" causes the output of chocolatey upgrades and installs to be shown.

Reference

For information on classes and types, see REFERENCE.md. For information on facts, see below.

Facts

• chocolateyversion - The version of the installed Chocolatey client (could also be informationally provided by class parameter chocolatey_version).
• choco_install_path - The location of the installed Chocolatey client (could also be provided by class parameter choco_install_location).

Limitations

• The module is only suppported on Windows. For an extensive list of supported operating systems, see metadata.json
• If you override an existing install location of Chocolatey using choco_install_location => in the Chocolatey class, it does not bring any of the existing packages with it. You will need to handle that through some other means.
• Overriding the install location will also not allow Chocolatey to be configured or install packages on the same run that it is installed on. See choco_install_location for details.

Known Issues

• This module doesn't support side by side scenarios.
• This module may have issues upgrading Chocolatey itself using the package resource.
• If .NET 4.0 is not installed, it may have trouble installing Chocolatey. Chocolatey version 0.9.9.9+ helps alleviate this issue.
• If there is an error in the installer (InstallChocolatey.ps1.erb), it may not show as an error. This may be an issue with the PowerShell provider and is still under investigation.

Development

Acceptance tests for this module leverage puppet_litmus. To run the acceptance tests follow the instructions here. You can also find a tutorial and walkthrough of using Litmus and the PDK on YouTube.

If you run into an issue with this module, or if you would like to request a feature, please file a ticket. Every Monday the Puppet IA Content Team has office hours in the Puppet Community Slack, alternating between an EMEA friendly time (1300 UTC) and an Americas friendly time (0900 Pacific, 1700 UTC).

If you have problems getting this module up and running, please contact Support.

If you submit a change to this module, be sure to regenerate the reference documentation as follows:

puppet strings generate --format markdown --out REFERENCE.md

Attributions

A special thanks goes out to Rich Siegel and Rob Reynolds who wrote the original provider and continue to contribute to the development of this provider.

Reference

Table of Contents

Classes

Public Classes

• chocolatey: Used for managing installation and configuration of Chocolatey itself.

Private Classes

• chocolatey::config: Handles configuration of Chocolatey
• chocolatey::install: Handles installation of Chocolatey

Resource types

• chocolateyconfig: Allows managing config settings for Chocolatey. Configuration values provide settings for users to configure aspects of Chocolatey and the wa
• chocolateyfeature: Allows managing features for Chocolatey. Features are configuration that act as feature flippers to turn on or off certain aspects of how Cho
• chocolateysource: Allows managing sources for Chocolatey. A source can be a folder, a CIFS share, a NuGet Http OData feed, or a full Package Gallery. Learn mor

Tasks

• init: Manage a package
• outdated: List outdated packages
• pin: Manage package pinning
• status: List currently installed packages

Classes

chocolatey

Used for managing installation and configuration of Chocolatey itself.

Examples

Default - This will by default ensure Chocolatey is installed and ready for use.

include chocolatey

Override default install location

class {'chocolatey':
  choco_install_location => 'D:\secured\choco',
}

Use an internal Chocolatey.nupkg for installation

class {'chocolatey':
  chocolatey_download_url         => 'https://internalurl/to/chocolatey.nupkg',
  use_7zip                        => false,
  choco_install_timeout_seconds   => 2700,
}

Use a file chocolatey.0.9.9.9.nupkg for installation

class {'chocolatey':
  chocolatey_download_url         => 'file:///c:/location/of/chocolatey.0.9.9.9.nupkg',
  use_7zip                        => false,
  choco_install_timeout_seconds   => 2700,
}

Log chocolatey bootstrap installer script output

class {'chocolatey':
  log_output              => true,
}

Disable autouninstaller (use when less than 0.9.9.8)

class {'chocolatey':
  enable_autouninstaller => false,
}

Parameters

The following parameters are available in the chocolatey class:

• choco_install_location
• use_7zip
• seven_zip_download_url
• choco_install_timeout_seconds
• chocolatey_download_url
• enable_autouninstaller
• log_output
• chocolatey_version
• install_proxy

choco_install_location

Data type: Stdlib::Windowspath

Where Chocolatey install should be located. This needs to be an absolute path starting with a drive letter e.g. c:\. Defaults to the currently detected install location based on the ChocolateyInstall environment variable, falls back to 'C:\ProgramData\chocolatey'.

Default value: $facts['choco_install_path']

use_7zip

Data type: Boolean

Whether to use built-in shell or allow installer to download 7zip to extract chocolatey.nupkg during installation. Defaults to false.

Default value: false

seven_zip_download_url

Data type: String[1]

Specifies the source file for 7za.exe. Supports all sources supported by Puppet's file resource. You should use a 32bit binary for compatibility. Defaults to 'https://chocolatey.org/7za.exe'.

Default value: 'https://chocolatey.org/7za.exe'

choco_install_timeout_seconds

Data type: Integer

How long in seconds should be allowed for the install of Chocolatey (including .NET Framework 4 if necessary). Defaults to 1500 (25 minutes).

Default value: 1500

chocolatey_download_url

Data type: Stdlib::Filesource

A url that will return chocolatey.nupkg. This must be a url, but not necessarily an OData feed. Any old url location will work. Defaults to 'https://chocolatey.org/api/v2/package/chocolatey/'.

Default value: 'https://chocolatey.org/api/v2/package/chocolatey/'

enable_autouninstaller

Data type: Boolean

[Deprecated] - Should auto uninstaller be turned on? Auto uninstaller is what allows Chocolatey to automatically manage the uninstall of software from Programs and Features without necessarily requiring a chocolateyUninstall.ps1 file in the package. Defaults to true. Setting is ignored in Chocolatey v0.9.10+.

Default value: true

log_output

Data type: Boolean

Log output from the installer. Defaults to false.

Default value: false

chocolatey_version

Data type: String[1]

• Informational parameter to tell Chocolatey what version to expect and to pre-load features with, falls back to $::chocolateyversion.

Default value: $facts['chocolateyversion']

install_proxy

Data type: Optional[String[1]]

Proxy server to use to use for installation of chocolatey itself or undef to not use a proxy

Default value: undef

Resource types

chocolateyconfig

Allows managing config settings for Chocolatey. Configuration values provide settings for users to configure aspects of Chocolatey and the way it functions. Similar to features, except allow for user configured values. Requires 0.9.10+. Learn more about config at https://chocolatey.org/docs/commands-config

Properties

The following properties are available in the chocolateyconfig type.

ensure

Valid values: present, absent

Specifies state of resource

Default value: present

value

The value of the config setting. If the name includes 'password', then the value is not ensurable due to being encrypted in the configuration file.

Parameters

The following parameters are available in the chocolateyconfig type.

• name
• provider

name

namevar

The name of the config setting. Used for uniqueness. Puppet is not able to easily manage any values that include Password in the key name in them as they will be encrypted in the configuration file.

provider

The specific backend to use for this chocolateyconfig resource. You will seldom need to specify this --- Puppet will usually discover the appropriate provider for your platform.

chocolateyfeature

Allows managing features for Chocolatey. Features are configuration that act as feature flippers to turn on or off certain aspects of how Chocolatey works. Learn more about features at https://chocolatey.org/docs/commands-feature

Properties

The following properties are available in the chocolateyfeature type.

ensure

Valid values: enabled, disabled

Specifies state of resource

Parameters

The following parameters are available in the chocolateyfeature type.

• name
• provider

name

namevar

The name of the feature. Used for uniqueness.

provider

The specific backend to use for this chocolateyfeature resource. You will seldom need to specify this --- Puppet will usually discover the appropriate provider for your platform.

chocolateysource

Allows managing sources for Chocolatey. A source can be a folder, a CIFS share, a NuGet Http OData feed, or a full Package Gallery. Learn more about sources at https://chocolatey.org/docs/how-to-host-feed

Properties

The following properties are available in the chocolateysource type.

admin_only

Valid values: true, false

Option to specify whether this source should visible to Windows user accounts in the Administrators group only.

Requires Chocolatey for Business (C4B) v1.12.2+ and at least Chocolatey v0.10.8 for the setting to be respected. Defaults to false.

Default value: false

allow_self_service

Valid values: true, false

Option to specify whether this source should be allowed to be used with Chocolatey Self Service.

Requires Chocolatey for Business (C4B) v1.10.0+ with the feature useBackgroundServiceWithSelfServiceSourcesOnly turned on in order to be respected. Also requires at least Chocolatey v0.10.4 for the setting to be enabled. Defaults to false.

Default value: false

bypass_proxy

Valid values: true, false

Option to specify whether this source should explicitly bypass any explicitly or system configured proxies. Requires at least Chocolatey v0.10.4. Defaults to false.

Default value: false

ensure

Valid values: present, disabled, absent

Specifies state of resource

Default value: present

location

The location of the source repository. Can be a url pointing to an OData feed (like chocolatey/chocolatey_server), a CIFS (UNC) share, or a local folder. Required when ensure => present (the default for ensure).

priority

Optional priority for explicit feed order when searching for packages across multiple feeds. The lower the number the higher the priority. Sources with a 0 priority are considered no priority and are added after other sources with a priority number. Requires at least Chocolatey v0.9.9.9. Defaults to 0.

Default value: 0

user

Optional user name for authenticated feeds. Requires at least Chocolatey v0.9.9.0. Defaults to nil. Specifying an empty value is the same as setting the value to nil or not specifying the property at all.

Default value: ''

Parameters

The following parameters are available in the chocolateysource type.

• name
• password
• provider

name

namevar

The name of the source. Used for uniqueness.

password

Optional user password for authenticated feeds. Not ensurable. Value is not able to be checked with current value. If you need to update the password, update another setting as well. Requires at least Chocolatey v0.9.9.0. Defaults to nil. Specifying an empty value is the same as setting the value to nil or not specifying the property at all.

Default value: ''

provider

The specific backend to use for this chocolateysource resource. You will seldom need to specify this --- Puppet will usually discover the appropriate provider for your platform.

Tasks

init

Manage a package

Supports noop? false

Parameters

action

Data type: Enum[install,upgrade,uninstall]

Action to perform

package

Data type: String[1]

Package to manipulate

version

Data type: Optional[String[1]]

Use a specific version

outdated

List outdated packages

Supports noop? false

pin

Manage package pinning

Supports noop? false

Parameters

action

Data type: Enum[list,add,remove]

Action to perform

package

Data type: Optional[String[1]]

Package to manipulate

version

Data type: Optional[String[1]]

Use a specific version

status

List currently installed packages

Supports noop? false

Changelog

All notable changes to this project will be documented in this file.

The format is based on Keep a Changelog and this project adheres to Semantic Versioning.

v8.0.0 - 2023-05-31

Full Changelog

Added

• (CONT-596) - Updating readme with deferred function for sensitive fields #325 (Ramesh7)

Changed

• (CONT-774) Puppet 8 support / Drop Puppet 6 #316 (LukasAud)

Fixed

• (CONT-898) Address Sorted_set failing gems #318 (LukasAud)

v7.0.1 - 2023-03-16

Full Changelog

Fixed

• (CONT-708) Set all execute's to run with sensitive #310 (david22swan)

v7.0.0 - 2022-10-31

Full Changelog

Changed

• (GH-297) Raise minimum puppet version required #298 (LukasAud)

v6.2.1 - 2022-10-03

Full Changelog

Fixed

• (MAINT) Dropping of support for windows 7,8.1, 2008/2008R2 (Server) #300 (jordanbreen28)

v6.2.0 - 2022-05-16

Full Changelog

Added

• update holdable feature #270 (rico89)

v6.1.1 - 2022-04-11

Full Changelog

Fixed

• (GH-283) Fix deprecation error #286 (chelnak)

v6.1.0 - 2022-03-08

Full Changelog

Added

• pdksync - (FM-8922) - Add Support for Windows 2022 #278 (david22swan)
• (MODULES-11255) Add basic tasks to manage packages #273 (smortex)
• add support for version range #269 (rico89)

v6.0.1 - 2021-04-19

Full Changelog

Fixed

• (MODULES-10638) Ease mocking of chocolatey internals #254 (DavidS)

v6.0.0 - 2021-03-03

Full Changelog

Changed

• pdksync - Remove Puppet 5 from testing and bump minimal version to 6.0.0 #248 (carabasdaniel)

Fixed

• (MODULES-10704) - Have the code error out rather than return nil values when finding version #247 (david22swan)

v5.2.1 - 2021-01-11

Full Changelog

Fixed

• Add back error fix for (MODULES-3677) #241 (daianamezdrea)

v5.2.0 - 2020-12-09

Full Changelog

Added

• pdksync - (feat) - Add support for Puppet 7 #236 (daianamezdrea)

v5.1.1 - 2020-08-28

Full Changelog

Fixed

• (MODULES-10791) Increase upper boundary for powershell dependency to 5.0.0 #228 (adrianiurca)

v5.1.0 - 2020-08-26

Full Changelog

Added

• (IAC-980) - Removal of inappropriate terminology #224 (david22swan)
• pdksync - (IAC-973) - Update travis/appveyor to run on new default branch main #219 (david22swan)

Fixed

• [MODULES-10759] - set a default value if custom facts fails #223 (adrianiurca)

v5.0.2 - 2020-01-16

Full Changelog

Fixed

• MODULES-10387 - update dependencies #198 (lionce)

v5.0.1 - 2019-12-09

Full Changelog

v5.0.0 - 2019-10-14

Full Changelog

Changed

• Use datatypes and facts hash. Remove logic for Puppet 3.x #175 (treydock)

Fixed

• (MODULES-8521) Fix $chocolatey_version parameter #103 (helge000)

v4.1.0 - 2019-08-19

Full Changelog

Added

• (MODULES-9690) Redact Sensitive Commandline #168 (RandomNoun7)

v4.0.0 - 2019-07-30

Full Changelog

Added

• (MODULES-9317) Add Puppet Strings docs #162 (eimlav)
• (FM-8194) Convert tests to litmus #156 (eimlav)
• (MODULES-9224) Add no progress flag #154 (michaeltlombardi)

Changed

• (MODULES-9310) Raise lower Puppet bound to 5.5.10 #159 (eimlav)

3.3.0 - 2019-03-19

Full Changelog

Added

• (MODULES-6652) Fix download 7z behind proxy #94 (helge000)

Fixed

• (MODULES-8491) Warn about install_options secrets #147 (michaeltlombardi)
• (MODULES-8047) Fix puppet resource chocolateyconfig #146 (michaeltlombardi)

3.2.0 - 2019-02-20

Full Changelog

Added

• (MODULES-5897) Add allow_self_service to chocolateysource #137 (michaeltlombardi)
• (MODULES-5898) add admin_only to chocolateysource #135 (michaeltlombardi)
• (MODULES-4418) Add bypass_proxy to chocolateysource #132 (michaeltlombardi)
• MODULES-7068 Only initialise constant when not defined #104 (btoonk)
• (MODULES-5654) Support for proxies during installation #87 (GeoffWilliams)
• (MODULES-5383) Remove exit codes arg with feature #84 (davidtwco)

Fixed

• (MAINT) Fix broken state which causes CI to fail #140 (michaeltlombardi)
• (MODULES-8400) PDK Sync to fix Travis #129 (RandomNoun7)
• (MODULES-6948) Fix/generate types chocolateyfeature #111 (rico89)
• (MODULES-8493) Fix Source Syntax #105 (jcwest)

3.1.1 - 2018-12-12

Full Changelog

Added

• (WIN-231) Change curl_on command to add path to cacert bundle #120 (ThoughtCrhyme)

Fixed

• (MODULES-5859) Fix An already initialized constant' warning when doing a "puppet apply" #89 (psreed)

3.1.0 - 2018-10-08

Full Changelog

Fixed

• (MODULES-6746) Convert Tests to RSpec #98 (RandomNoun7)
• add choco_ver variable and string it #88 (tek0011)

3.0.0 - 2017-06-02

Full Changelog

Fixed

• (MODULES-4562) Use actual choco.exe #77 (ferventcoder)
• (MODULES-4678) Explicitly close config on read #76 (ferventcoder)

2.0.2 - 2017-04-04

Full Changelog

Fixed

• (Modules-4508) Fixed error with version parameter #69 (derek-robinson)

2.0.1 - 2017-01-03

Full Changelog

Fixed

• (MODULES-4056) Helpful Error if No Sources Enabled #57 (ferventcoder)
• (MODULES-4210) Do not use com unzip in PS 5+ #56 (helge000)
• (MODULES-4149) Unsuitable providers should not error #54 (ferventcoder)
• (MODULES-4091) Explicitly Set ChocolateyInstall Environment #53 (ferventcoder)
• (MODULES-4135) choco -v - Remove all extraneous messaging #52 (ferventcoder)

2.0.0 - 2016-09-29

Full Changelog

Added

• (MODULES-3677) Ensure Chocolatey Config #37 (ferventcoder)

Fixed

• (MODULES-3880) Ignore Package Exit Codes #46 (ferventcoder)
• (MODULES-3758) Fix: chocolateysource user ensure sync #42 (ferventcoder)
• (MODULES-3430) Do not set default location to resource title #41 (ferventcoder)
• (MODULES-3391) Limit rake spec on older puppet #36 (MosesMendoza)
• (Modules 3391) remove rake test and fix failing test #35 (MosesMendoza)
• (MODULES-3641) Remove Windows_env module dependency #34 (ferventcoder)

0.8.0 - 2016-07-13

Full Changelog

Changed

• (MODULES-3490) Sync from Community Repo #28 (ferventcoder)

1.2.6 - 2016-07-11

Full Changelog

Added

• (MODULES-3035) Manage configuration settings #17 (ferventcoder)

Fixed

• (MODULES-3275) fix VLC uninstall command #30 (ThoughtCrhyme)
• (MODULES-3275) Chocolatey module testing #26 (ThoughtCrhyme)

1.2.5 - 2016-06-20

Full Changelog

Added

• (MODULES-3034) Feature Configuration #24 (ferventcoder)

1.2.4 - 2016-06-04

Full Changelog

0.7.0 - 2016-06-01

Full Changelog

Added

• (MODULES-3043) add acceptance and reference test for choco install #14 (ThoughtCrhyme)
• (MODULES-3037) Manage sources #1 (ferventcoder)

Fixed

• (MODULES-3037) Acceptance tests - ChocolateySource #21 (ThoughtCrhyme)
• (MODULES-3037) Acceptance tests - ChocolateySource #20 (ferventcoder)
• (MODULES-3037) Confine version fact w/default #19 (ferventcoder)
• (MODULES-3037) Confine install path fact w/default #18 (ferventcoder)
• Change templates to use windows 2008r2 without wmf5 #16 (ThoughtCrhyme)

1.2.3 - 2016-05-06

Full Changelog

Added

• Tests/master/modules 3138 #11 (ThoughtCrhyme)
• (MODULES-3138) Added presuites #10 (ThoughtCrhyme)

Fixed

• Tests/master/modules 3138 #12 (ThoughtCrhyme)

1.2.2 - 2016-04-06

Full Changelog

Added

• (MODULES-3161) Add acceptance test harness #8 (glennsarti)
• (MODULES-3161) Add rake tests task #5 (glennsarti)

1.2.1 - 2015-12-08

Full Changelog

1.2.0 - 2015-11-03

Full Changelog

1.1.2 - 2015-10-02

Full Changelog

1.1.1 - 2015-09-25

Full Changelog

1.1.0 - 2015-09-09

Full Changelog

1.0.2 - 2015-07-23

Full Changelog

1.0.1 - 2015-07-01

Full Changelog

1.0.0 - 2015-06-08

Full Changelog

0.5.3 - 2015-05-22

Full Changelog

0.5.2 - 2015-04-23

Full Changelog

0.5.1 - 2015-03-31

Full Changelog

0.5.0 - 2015-03-30

Full Changelog

0.4.0 - 2014-12-22

Full Changelog

help - 2014-12-22

Full Changelog

0.3 - 2014-08-18

Full Changelog

0.2 - 2013-11-19

Full Changelog